REAL FUNCTION RPV_REFLECTION (RHO0, K, THETA, MU1, MU2, PHI)
C       Computes the Rahman, Pinty, Verstraete BRDF.  The incident
C     and outgoing cosine zenith angles are MU1 and MU2, respectively,
C     and the relative azimuthal angle is PHI.  In this case the incident
C     direction is where the radiation is coming from (i.e. opposite of the
C     discrete ordinate), so MU1>0 and the hot spot is MU2=MU1 and PHI=0.
C     The reference is:
C       Rahman, Pinty, Verstraete, 1993: Coupled Surface-Atmosphere 
C       Reflectance (CSAR) Model. 2. Semiempirical Surface Model Usable 
C       With NOAA Advanced Very High Resolution Radiometer Data,
C       J. Geophys. Res., 98, 20791-20801.
      REAL RHO0, K, THETA, MU1, MU2, PHI
      REAL M, F, H, COSPHI, SIN1, SIN2, COSG, TAN1, TAN2, CAPG

      M = MU1**(K-1) * MU2**(K-1) / (MU1 + MU2)**(1-K)
      COSPHI = COS(PHI)
      SIN1 = SQRT(1.0-MU1**2)
      SIN2 = SQRT(1.0-MU2**2)
      COSG = MU1*MU2 + SIN1*SIN2*COSPHI
      F = (1-THETA**2) / (1 + 2*THETA*COSG + THETA**2)**1.5
      TAN1 = SIN1/MU1
      TAN2 = SIN2/MU2
      CAPG = SQRT( TAN1**2 + TAN2**2 - 2*TAN1*TAN2*COSPHI )
      H = 1 + (1-RHO0)/(1+CAPG)
      RPV_REFLECTION = RHO0 * M * F * H

      RETURN
      END